source: providers/adaptive/src/com/longtailvideo/jwplayer/parsing/Manifest.as @ 1506

package com.longtailvideo.jwplayer.parsing {


    import com.longtailvideo.jwplayer.parsing.*;
    import com.longtailvideo.jwplayer.utils.*;
    import flash.events.*;
    import flash.net.*;


    /**
    * Parser for Apple HLS manifests.
    * 
    * @todo: Support live streaming (reloading / discontinuities / dvrwindow)
    **/
    public class Manifest extends EventDispatcher {


        /** Header tag that must be at the first line. **/
        private const TAG_HEADER:String = '#EXTM3U';
        /** Starttag for a level. **/
        private const TAG_LEVEL:String = '#EXT-X-STREAM-INF:';
        /** Stream identifier bandwidth parameter. **/
        private const PARAM_BANDWIDTH:String = 'BANDWIDTH';
        /** Stream identifier bandwidth parameter. **/
        private const PARAM_RESOLUTION:String = 'RESOLUTION';


        /** Array with levels. **/
        public var levels:Array;
        /** Object that fetches the manifest. **/
        private var _loader:URLLoader;
        /** Link to the M3U8 file. **/
        private var _url:String;
        /** Amount of playlists still need loading. **/
        private var _toLoad:Number;


        /** Setup the loader. **/
        public function Manifest() {
            _loader = new URLLoader();
            _loader.addEventListener(Event.COMPLETE,_loaderHandler);
            _loader.addEventListener(IOErrorEvent.IO_ERROR,_errorHandler);
            _loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR,_errorHandler);
        };


        /** Loading failed; return errors. **/
        private function _errorHandler(event:ErrorEvent):void {
            dispatchEvent(new ErrorEvent(
                ErrorEvent.ERROR,
                false,
                false,
                event.text
            ));
        };


        /** Load the manifest file. **/
        public function load(url:String):void {
            _url = url;
            _toLoad = 0;
            levels = new Array();
            _loader.load(new URLRequest(_url));
        };


        /** A level is loaded and parsed. **/
        private function _levelHandler(event:Event):void {
            _toLoad--;
            if(_toLoad == 0) {
                dispatchEvent(new Event(Event.COMPLETE));
            }
        };


        /** The manifest is loaded. **/
        private function _loaderHandler(event:Event):void {
            var lines:Array = String(event.target.data).split("\n");
            if(lines[0] != TAG_HEADER) {
                dispatchEvent(new ErrorEvent(
                    ErrorEvent.ERROR,
                    false,
                    false,
                    "First line of the Manifest not equal to #EXTM3U: " + _url
                ));
            }
            var i:Number = 0;
            while (i<lines.length) {
                if(lines[i].indexOf(TAG_LEVEL) == 0) {
                    _readLevel(lines,i);
                }
                i++;
            }
            if(levels.length == 0) {
                dispatchEvent(new ErrorEvent(
                    ErrorEvent.ERROR,
                    false,
                    false,
                    "No Playlists found in Manifest: " + _url 
                ));
            }
        };


        /** Parse a manifest for levels. **/
        private function _readLevel(lines:Array,index:Number):void {
            var level:Level = new Level();
            var params:Array = lines[index].substr(TAG_LEVEL.length).split(',');
            for(var j:Number = 0; j<params.length; j++) { 
                if(params[j].indexOf(PARAM_BANDWIDTH) == 0) {
                    level.bitrate = params[j].split('=')[1];
                } else if (params[j].indexOf(PARAM_RESOLUTION) == 0) {
                    level.height  = params[j].split('=')[1].split('x')[1];
                    level.width = params[j].split('=')[1].split('x')[0];
                }
            }
            levels.push(level);
            var playlist:Playlist = new Playlist(level);
            playlist.addEventListener(ErrorEvent.ERROR, _errorHandler);
            playlist.addEventListener(Event.COMPLETE, _levelHandler);
            var url:String = _gluePaths(lines[index+1],_url);
            playlist.load(url);
            _toLoad++;
        };


        /** Glue the playlist path to the manifest path. **/
        private function _gluePaths(path:String,base:String):String {
            if(path.indexOf('http') == 0) { 
                return path;
            } else {
                return base.substr(0,base.lastIndexOf('/') + 1) + path;
            }
        };


    }


}