source: providers/adaptive/src/com/longtailvideo/jwplayer/muxing/FLV.as @ 1506

package com.longtailvideo.jwplayer.muxing {


        import com.longtailvideo.jwplayer.utils.Logger;
        import com.longtailvideo.jwplayer.muxing.*;
        import flash.utils.ByteArray;


        /** Representation of an FLV file. **/
        public class FLV {


                /** List of FLV tags. **/
                private var _tags:Array;
                /** Is this the first video? **/
                private var _first:Boolean;


                /** Transmux the M2TS file into an FLV file. **/
                public function FLV(first:Boolean=false) {
                        _tags = new Array();
                        _first = first;
                };


                /** Return the bytes for the player. **/
                public function get data():ByteArray {
                        var flv:ByteArray = new ByteArray();
                        if(_first) { 
                            _writeHeader(flv);
                    }
                        // Sort the tags by timestamp; private data first.
                        _tags.sortOn(
                                ['timestamp','isPrivate'],
                                [Array.NUMERIC, Array.NUMERIC | Array.DESCENDING]
                        );
                        //var stt:Number = _tags[0].timestamp;
                        // Append all tags
                        var pos:Number = flv.position;
                        for(var i:Number=0; i<_tags.length; i++) {
                                // Set the timestamps zero-indexed.
                                //_tags[i].timestamp -= stt;
                                // The Tag itself.
                                //if(_first || !_tags[i].isPrivate) {
                                    flv.writeBytes(_tags[i].data);
                                    flv.writeUnsignedInt(flv.position - pos);
                                    pos = flv.position;
                            //}
                        }
                        // Add an end-of-sequence tag.
                        // _writeEOSTag(flv);
                        Logger.log("timestamps from " + _tags[0].timestamp + " to " +_tags[_tags.length-1].timestamp);
                        return flv;
                };


                /** Push an FLV tag into the FLV file. **/
                public function push(tag:FLVTag):void {
                        _tags.push(tag);
                };


                /** Write end-of-sequence FLV tag. **/
                private function _writeEOSTag(tag:ByteArray):void { 
                        // Size of the tag in bytes after StreamID.
                        tag.writeUnsignedInt(0x09000005);
                        // Timestamp (lower 24 plus upper 8)
                        var tsp:Number = _tags[_tags.length-1].timestamp + 1;
                        tag.writeByte(tsp >> 16);
                        tag.writeByte(tsp >> 8);
                        tag.writeByte(tsp);
                        tag.writeByte(tsp >> 24);
                        // StreamID (3 empty bytes), Keyframe, AVC.
                        tag.writeUnsignedInt(0x00000017);
                        //Sequence end, composition time
                        tag.writeUnsignedInt(0x02000000);
                        // PreviousTagSize
                        tag.writeUnsignedInt(0x00000016);
                };


                /** Write the FLV file header. **/
                private function _writeHeader(flv:ByteArray):void {
                        // "F" + "L" + "V".
                        flv.writeByte(0x46);
                        flv.writeByte(0x4C);
                        flv.writeByte(0x56);
                        // File version (1)
                        flv.writeByte(0x01);
                        // Audio + Video tags.
                        flv.writeByte(0x05);
                        // Length of the header.
                        flv.writeUnsignedInt(0x00000009);
                        // PreviousTagSize0
                        flv.writeUnsignedInt(0x00000000);
                };


        }


}