source: providers/adaptive/src/com/longtailvideo/jwplayer/media/AdaptiveProvider.as @ 1484

package com.longtailvideo.jwplayer.media {


        import com.longtailvideo.jwplayer.events.MediaEvent;
        import com.longtailvideo.jwplayer.media.MediaProvider;
        import com.longtailvideo.jwplayer.model.PlayerConfig;
        import com.longtailvideo.jwplayer.model.PlaylistItem;
        import com.longtailvideo.jwplayer.player.PlayerState;
        import com.longtailvideo.jwplayer.muxing.*;
        import com.longtailvideo.jwplayer.utils.*;

        import flash.events.*;
        import flash.media.*;
        import flash.net.*;
        import flash.system.*;
        import flash.utils.*;


        /** JW Player provider for playback of adaptive streams. **/
        public class AdaptiveProvider extends MediaProvider {


                /** Video object to be instantiated. **/
                private var _video:Video;
                /** NetConnection object for setup of the video _stream. **/
                private var _connection:NetConnection;
                /** NetStream instance that handles the stream IO. **/
                private var _stream:NetStream;
                /** Sound control object. **/
                private var _transformer:SoundTransform;
                /** ID for the position interval. **/
                private var _positionInterval:Number;
                /** Whether the buffer has filled **/
                private var _bufferFull:Boolean;
                /** Save the buffer percentage. **/
                private var _bufferPercent:Number;
                /** URLStream that loads the file. **/
                private var _urlStream:URLStream;
                /** URLRequest for loading the stream. **/
                private var _urlRequest:URLRequest;
                /** Reference to the ts. **/
                private var _ts:TS;


                /** Constructor; sets up the connection and display. **/
                public function AdaptiveProvider() {
                        super('adaptive');
                }


                public override function initializeMediaProvider(cfg:PlayerConfig):void {
                        super.initializeMediaProvider(cfg);
                        _connection = new NetConnection();
                        _connection.connect(null);
                        _stream = new NetStream(_connection);
                        _stream.addEventListener(IOErrorEvent.IO_ERROR, errorHandler);
                        _stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, errorHandler);
                        _stream.bufferTime = config.bufferlength;
                        _stream.client = new Object();
                        _transformer = new SoundTransform();
                        _urlStream = new URLStream();
                        _urlStream.addEventListener(Event.COMPLETE, fileLoaded);
                        _video = new Video(320,240);
                        _video.smoothing = config.smoothing;
                        _video.attachNetStream(_stream);
                }


                /** Catch security errors. **/
                protected function errorHandler(evt:ErrorEvent):void {
                        Logger.log(evt.text,provider);
                        error(evt.text);
                }


                /** Load content. **/
                override public function load(itm:PlaylistItem):void {
                        media = _video;
                        _bufferFull = false;
                        _stream.play(null);
                        _urlStream.load(new URLRequest(itm.file));
                        _item = itm;
                        super.load(itm);
                        setState(PlayerState.BUFFERING);
                        sendBufferEvent(0);
                        streamVolume(config.mute ? 0 : config.volume);
                        clearInterval(_positionInterval);
                        _positionInterval = setInterval(positionHandler, 200);
                        resize(_width, _height);
                };


                private function fileLoaded(e:Event):void {
                        var input:ByteArray = new ByteArray();
                        _urlStream.readBytes(input);
                        _stream.appendBytesAction(NetStreamAppendBytesAction.RESET_BEGIN);
                        if(item.file.substr(-3) != 'flv') { 
                                _ts = new TS(input);
                                _stream.appendBytes(_ts.data);
                        } else {
                                _stream.appendBytes(input);
                        }
                        _bufferPercent = 100;
                        sendBufferEvent(100, 0, {});
                        _bufferFull = true;
                        sendMediaEvent(MediaEvent.JWPLAYER_MEDIA_BUFFER_FULL);
                };


                /** Pause playback. **/
                override public function pause():void {
                        _stream.pause();
                        super.pause();
                };


                /** Resume playing. **/
                override public function play():void {
                        if (!_positionInterval) {
                                _positionInterval = setInterval(positionHandler, 100);
                        }
                        if (_bufferFull) {
                                _stream.resume();
                                super.play();
                        } else {
                                setState(PlayerState.BUFFERING);
                        }
                };


                /** Interval for the position progress **/
                protected function positionHandler():void {
                        var pos:Number = Math.round(_stream.time * 10) / 10;
                        if (state == PlayerState.PLAYING && pos > 0) {
                                _position = pos;
                                sendMediaEvent(MediaEvent.JWPLAYER_MEDIA_TIME, {position: position, duration: item.duration});
                                if (item.duration > 0 && _position >= item.duration - 0.2) {
                                        stop();
                                        sendMediaEvent(MediaEvent.JWPLAYER_MEDIA_COMPLETE);
                                }
                        }
                };


                /** Seek to a new position. **/
                override public function seek(pos:Number):void {
                        /* Small files; seeking not very useful */
                };


                /** Destroy the video. **/
                override public function stop():void {
                        _stream.seek(0);
                        _stream.pause();
                        _bufferFull = false;
                        _bufferPercent = 0;
                        clearInterval(_positionInterval);
                        super.stop();
                };


                /** Set the volume level. **/
                override public function setVolume(vol:Number):void {
                        streamVolume(vol);
                        super.setVolume(vol);
                        var fr:FileReference = new FileReference( );
                        fr.save(_ts.data,'export.flv');
                };


                /** Set the stream's volume, without sending a volume event **/
                protected function streamVolume(level:Number):void {
                        _transformer.volume = level / 100;
                        if (_stream) {
                                _stream.soundTransform = _transformer;
                        }
                };


        }
}