source: plugins/related/src/as/Related.as @ 1938

package {

    import com.longtailvideo.jwplayer.events.*;
    import com.longtailvideo.jwplayer.player.*;
    import com.longtailvideo.jwplayer.plugins.*;
    import com.longtailvideo.jwplayer.utils.*;
    import com.longtailvideo.jwplayer.parsers.*;

    import flash.display.*;
    import flash.events.*;
    import flash.filters.DropShadowFilter;
    import flash.net.*;
    import flash.text.*;


    /** This plugin displays an overlay with related videos. **/
    public class Related extends Sprite implements IPlugin {


        /** Embedding the image assets. **/
        [Embed(source="../../assets/icon.png")]
        private const DockIcon:Class;
        [Embed(source="../../assets/sheet.png")]
        private const BackSheet:Class;


        /** Reference to the background sheet. **/
        private var _back:Sprite;
        /** Reference to the dock button. **/
        private var _button:MovieClip;
        /** The plugin configuration options.**/
        private var _config:Object;
        /** Number of columns and rows in the grid. **/
        private var _dimensions:Array;
        /** Link to the mRSS file with related videos. **/
        private var _file:String;
        /** The grid with all thumbs. **/
        private var _grid:Sprite;
        /** The CTA text heading. **/
        private var _heading:TextField;
        /** Reference to the dock icon. **/
        private var _icon:DisplayObject;
        /** Component that loads the related videos. **/
        private var _loader:URLLoader;
        /** Component that parses the related videos. **/
        private var _parser:RSSParser;
        /** Reference to the player. **/
        private var _player:IPlayer;


        /** The background screen was clicked. **/
        private function _backHandler(evt:MouseEvent):void { hide(); };


        /** Display the related items on complete. **/
        private function _completeHandler(evt:MediaEvent):void { 
            if(_config.oncomplete !== false) { show(); }
        };


        /** The controlbar/dock button was clicked. **/
        private function _dockHandler(evt:MouseEvent):void { show(); };


        /** Loading the RSS feed failed. **/
        private function _errorHandler(evt:ErrorEvent):void {
            Logger.log(evt.text,id);
            _file = undefined;
            if(_icon) {
                _icon.alpha = 0.5;
                _button.field.alpha = 0.5;
                _button.field.text = 'not set';
            }
        };


        /** Hide the list with related videos. **/
        public function hide():void {
            _back.visible = false;
            _grid.visible = false;
            _heading.visible = false;
            // Only 5.7+...
            try { (_player.controls.display as Object).show(); } catch (error:Error) {}
        };


        /** Returns the plugin name. **/
        public function get id():String {
            return "related";
        };


        /** Called by the player to initialize; setup events and dock buttons.  */
        public function initPlugin(player:IPlayer, config:PluginConfig):void {
            _player = player;
            _config = config;
            _player.addEventListener(MediaEvent.JWPLAYER_MEDIA_COMPLETE, _completeHandler);
            _player.addEventListener(PlaylistEvent.JWPLAYER_PLAYLIST_ITEM, _itemHandler);
            _loader = new URLLoader();
            _loader.addEventListener(Event.COMPLETE,_loaderHandler);
            _loader.addEventListener(SecurityErrorEvent.SECURITY_ERROR, _errorHandler);
            _loader.addEventListener(IOErrorEvent.IO_ERROR, _errorHandler);
            _parser = new RSSParser();
            if(_config.usedock !== false) {
                _icon = new DockIcon()
                _button = _player.controls.dock.addButton(_icon, "related", _dockHandler);
            }
            // Add the background sheet.
            _back = new Sprite();
            _back.visible = false;
            _back.buttonMode = true;
            _back.addChild(new BackSheet());
            _back.addEventListener(MouseEvent.CLICK,_backHandler);
            addChild(_back);
            // Add the text heading.
            _heading = new TextField();
            _heading.height = 30;
            _heading.defaultTextFormat = new TextFormat('Arial', 16, 0xFFFFFF, true);
            _heading.autoSize = 'center';
            _heading.multiline = false;
            _heading.selectable = false;
            _heading.filters = new Array(new DropShadowFilter(2,45,0,1,1,1,1));
            if(_config.heading) {
                _heading.htmlText = _config.heading;
            } else {
                _heading.htmlText = "Watch related videos";
            }
            addChild(_heading);
            // Add the grid for thumbs
            _grid = new Sprite();
            addChild(_grid);
            // Hide the graphics on startup.
            hide();
        };


        /** Find the related thumbs feed when an item loads.  */
        public function _itemHandler(evt:PlaylistEvent):void {
            // Reset old data
            _file = undefined;
            // Check for new file
            if(_player.playlist.currentItem['related.file']) {
                _file = _player.playlist.currentItem['related.file'];
            } else if (_config['file']) {
                _file = _config['file'];
            }
            // Load the mRSS feed and set the dock icon
            if(_file) {
                _loader.load(new URLRequest(_file));
                if(_icon) { 
                    _icon.alpha = 1;
                    _button.field.alpha = 1;
                    _button.field.text = 'related';
                }
            } else {
                _errorHandler(new ErrorEvent(ErrorEvent.ERROR,false,false,
                    "This playlist entry has no related videos."));
            }
        };


        /** Loader has loaded the mRSS feed. **/
        private function _loaderHandler(evt:Event):void {
            var xml:XML = XML(evt.target.data);
            var rss:Array = _parser.parse(xml);
            var related:Array = new Array();
            for (var i:Number = 0; i < rss.length; i++) {
                if(rss[i].title && rss[i].image && rss[i].link) { 
                    related.push(rss[i]);
                }
            }
            if(related.length) {
                Logger.log("Found "+related.length+" related videos",id);
                for(var j:Number = 0; j < related.length; j++) { 
                    var thumb:RelatedThumb = new RelatedThumb(related[j].image,related[j].link,related[j].title);
                    thumb.x = 130*j;
                    _grid.addChild(thumb);
                    resize(_back.width,_back.height);
                }
            } else {
                _errorHandler(new ErrorEvent(ErrorEvent.ERROR,false,false,
                    "RSS feed has 0 entries that contain title,link and image."));
            }
        };


        /** Reposition the screens when the player resizes itself **/
        public function resize(width:Number, height:Number):void {
            _back.width = width;
            _back.height = height;
            _grid.x = Math.round(width/2 - _grid.width/2);
            _grid.y = Math.round(height/2 - _grid.height/2) + 10;
            _heading.y = _grid.y - 30;
            _heading.x = Math.round(width/2 - _heading.width/2);
            _dimensions = new Array(
                Math.floor(width/130),
                Math.floor((height-30)/90)
            );
        };


        /** Show the list with related videos. **/
        public function show():void {
            if(_file) {
                _back.visible = true;
                _grid.visible = true;
                _heading.visible = true;
                // Only 5.7+...
                try { (_player.controls.display as Object).hide(); } catch (error:Error) {}
            }
        };


    }
}