source: plugins/ping/src/as/Ping.as @ 2007

package {


    import com.longtailvideo.jwplayer.events.*;
    import com.longtailvideo.jwplayer.player.*;
    import com.longtailvideo.jwplayer.plugins.*;

    import flash.display.Sprite;
    import flash.external.ExternalInterface;
    import flash.net.sendToURL;
    import flash.net.URLRequest;
    import flash.utils.setTimeout;


    /** JW Player plugin that pings playback events back to server. **/
    public class Ping extends Sprite implements IPlugin {


        /** Plugin configuration. **/
        private var _config:Object = {
            interval: 30,
            pixel: undefined,
            playerid: undefined
        };
        /** Current playlist item. **/
        private var _item:Object;
        /** Error message. **/
        private var _message:String;
        /** Reference to the  player. **/
        private var _player:IPlayer;
        /** Page referrer. **/
        private var _referrer:String;
        /** Start time **/
        private var _startTime:Number = -1;
        /** Last time tick **/
        private var _lastTime:Number = -1;


        /** Video ended; ping the server. **/
        private function _completeHandler(evt:MediaEvent):void {
            _sendPing('complete');
        };


        /** Error occured; ping the server. **/
        private function _errorHandler(evt:MediaEvent):void {
            _message = evt.message;
            _sendPing('error');
        };


        /** Setup the listeners and the browser unload pingback. **/
        public function initPlugin(player:IPlayer, cfg:PluginConfig):void {
            // Set options
            _player = player;
            if(cfg.interval) { 
                _config.interval = cfg.interval; 
            }
            _config.pixel = cfg.pixel;
            _config.playerid = _player.config.id;
            // Add listeners.
            _player.addEventListener(MediaEvent.JWPLAYER_MEDIA_COMPLETE, _completeHandler);
            _player.addEventListener(MediaEvent.JWPLAYER_MEDIA_ERROR, _errorHandler);
            _player.addEventListener(MediaEvent.JWPLAYER_MEDIA_TIME, _timeHandler);
            _player.addEventListener(PlayerStateEvent.JWPLAYER_PLAYER_STATE, _stateHandler);
            // Try connecting to JavaScript
            try {
                // Get ID of player in HTML DOM.
                if(ExternalInterface.objectID) {
                    _config.playerid = ExternalInterface.objectID;
                }
                // Grab referrer from javascript.
                _referrer = ExternalInterface.call("function(){return window.location.href;}");
                // Register a JavaScript > Flash callback.
                ExternalInterface.addCallback("navigationAlert", _unloadHandler);
                // Use attachEvent (IE 7/8/9) to connect callback to unload.
                ExternalInterface.call("function() {try {eval(function playerCallback(evt){try {document.getElementById('"+_config.playerid+"').navigationAlert();}catch(err){}setTimeout('true;',1000);});var r = window.attachEvent('onbeforeunload', playerCallback);return r;}catch(err){}}");
                // Use addListener (Chrome/Firefox/Safari) to connect callback to unload.
                ExternalInterface.call("function() {try {window.addEventListener('beforeunload',function(){document.getElementById('"+_config.playerid+"').navigationAlert();setTimeout('true;',1000);},false);} catch(err) {}}");
            } catch(err:Error) {}
            _sendPing("ready");
        };


        /** Let the player know what the name of your plugin is. **/
        public function get id():String { return "ping"; }


        /** Required resize function **/
        public function resize(wid:Number, hei:Number):void {}


        /** Event is caught; update the time **/
        private function _timeHandler(evt:MediaEvent):void {
            if (_startTime == -1) {
                _startTime = _lastTime = evt.position;
            } else if (Math.abs(evt.position - _lastTime) > 1) {
                // Ignore short seeks
                if(_lastTime - _startTime > 2) {
                    _sendPing('seek');
                }
                _startTime = -1;
                _lastTime = -1;
            } else if(_lastTime - _startTime > _config.interval) {
                _sendPing('progress');
                _startTime = _lastTime = evt.position;
            } else {
                _lastTime = evt.position;
            }
        }


        /** Wrap up the url generation and do the ping. **/
        private function _sendPing(event:String):void {
            // compose the query
            var query:String = '?event='+event;
            switch(event) {
                case 'error':
                    query += '&file='+encodeURIComponent(_item.file);
                    query += '&mediaid='+encodeURIComponent(_item.mediaid);
                    query += '&message=' + encodeURIComponent(_message);
                    break;
                case 'complete':
                case 'item':
                    query += '&file='+encodeURIComponent(_item.file);
                    query += '&mediaid='+encodeURIComponent(_item.mediaid);
                    break;
                case 'ready':
                    query += '&referrer=' + encodeURIComponent(_referrer);
                    query += '&playerid='+encodeURIComponent(_config.playerid);
                    query += '&renderingmode=flash';
                    break;
                case 'progress':
                case 'seek':
                case 'stop':
                    query += '&file='+encodeURIComponent(_item.file);
                    query += '&mediaid='+encodeURIComponent(_item.mediaid);
                    query += '&start=' + Math.round(_startTime*10)/10;
                    query += '&duration=' + Math.round((_lastTime-_startTime)*10)/10;
                    break;
            }
            // Add random hash to prevent caching
            query += '&r='+Math.random();
            // Request the pixel or send to log.
            if(_config.pixel) {
                sendToURL(new URLRequest(_config.pixel+query));
            }
        };


        /** Event is caught; ping the server. **/
        private function _stateHandler(evt:PlayerStateEvent):void {
            if(evt.newstate == PlayerState.BUFFERING && evt.oldstate == PlayerState.IDLE) {
                _item = _player.playlist.currentItem;
                _sendPing('item');
                _startTime = -1;
                _lastTime = -1;
            } else if (evt.newstate == PlayerState.IDLE && _startTime > -1) { 
                _sendPing('stop');
            };
        };


        /** This function is called when a browser navigation event occurs **/
        private function _unloadHandler():void {
            if (_startTime > -1) {
                _sendPing('stop');
            }
        };


    }


}