source: plugins/livestream/com/jeroenwijering/plugins/Livestream.as @ 214

package com.jeroenwijering.plugins {


import com.jeroenwijering.events.*;
import com.jeroenwijering.utils.Logger;

import flash.display.*;
import flash.events.*;
import flash.net.*;
import flash.utils.setTimeout;


/**
* This plugin automatically polls an RTMP stream for availability every XX seconds.
* If the stream is available, it will kick in.
* It allows users to wait for a live event without having to refresh their page.
**/
public class Livestream extends MovieClip implements PluginInterface {


        /** List with configuration settings. **/
        public var config:Object = {
                file:undefined,
                image:undefined,
                interval:15,
                message:'Checking for livestream...',
                streamer:undefined,
                tags:undefined
        };
        /** Reference to the graphics. **/
        public var clip:MovieClip;
        /** Reference to the view. **/
        private var view:AbstractView;
        /** Netconnection instance to check availability. **/
        private var connection:NetConnection;
        /** Netstream instance to check availability. **/
        private var stream:NetStream;
        /** The number times the plugin tried to connect. **/
        private var count:Number = 0;


        /** Constructor. **/
        public function Livestream():void {
                clip = this;
                connection = new NetConnection();
        };


        /** Try connecting to the livestream. **/
        private function checkStream():void {
                count++;
                connection.addEventListener(NetStatusEvent.NET_STATUS,statusHandler);
                connection.connect(config['streamer']);
                clip.visible = true;
                setTimeout(hideIcon,2000);
                Logger.log('checking for stream; attempt: '+count,'livestream');
        };


        /** Hide the icon again after a check. **/
        private function hideIcon():void {
                clip.visible = false;
        }


        /** 
        * Start the plugin.
        *
        * @param vie    A reference to the View of the player; the API entrypoint.
        **/
        public function initializePlugin(vie:AbstractView):void {
                view = vie;
                clip.visible = false;
                if(config['file'] && config['streamer'] &&
                        (config['tags'] == undefined || config['tags'] == view.config['tags'])) {
                        view.config['icons'] = false;
                        view.config['repeat'] = 'always';
                        setTimeout(checkStream,2000);
                        view.addControllerListener(ControllerEvent.RESIZE,resizeHandler);
                        clip.icon.txt.text = config['message'];
                }
        };


        /** The livestream is found. Now switch to it. **/
        private function loadStream():void {
                view.config['autostart'] = true;
                view.config['icons'] = true;
                view.config['repeat'] = 'none';
                var obj:Object = {
                        duration:0,
                        file:config['file'],
                        image:config['image'],
                        streamer:config['streamer'],
                        type:'rtmp'
                }
                view.sendEvent('LOAD',obj);
        };


        /** Reposition the icon on resize. **/
        private function resizeHandler(evt:ControllerEvent):void {
                clip.icon.x = config['x'] + config['width']/2;
                clip.icon.y = config['y'] + config['height']/2;
        };


        /** Receive NetStream status updates. **/
        private function statusHandler(evt:NetStatusEvent):void {
                switch(evt.info.code) {
                        case 'NetConnection.Connect.Success':
                                stream = new NetStream(connection);
                                stream.addEventListener(NetStatusEvent.NET_STATUS,statusHandler);
                                stream.play(config['file']);
                                Logger.log('connected to server '+config['streamer'],'livestream');
                                break;
                        case 'NetStream.Play.Start':
                                stream.removeEventListener(NetStatusEvent.NET_STATUS,statusHandler);
                                connection.removeEventListener(NetStatusEvent.NET_STATUS,statusHandler);
                                stream.close();
                                connection.close();
                                setTimeout(loadStream,2000);
                                Logger.log('found stream '+config['file'],'livestream');
                                break;
                        case 'NetStream.Play.StreamNotFound':
                        case 'NetConnection.Connect.Failed':
                                stream.removeEventListener(NetStatusEvent.NET_STATUS,statusHandler);
                                connection.removeEventListener(NetStatusEvent.NET_STATUS,statusHandler);
                                setTimeout(checkStream,config['interval']*1000);
                                Logger.log('no livestream yet: '+evt.info.code,'livestream');
                                break;
                }
        };



};


}