source: plugins/as3/com/jeroenwijering/plugins/Resizer.as @ 66

/**
* Shows a bar that can be dragged to resize the playlist.
**/
package com.jeroenwijering.plugins {


import com.jeroenwijering.events.*;
import flash.display.MovieClip;
import flash.events.MouseEvent;
import flash.geom.Rectangle;
import flash.utils.setInterval;
import flash.utils.clearInterval;


public class Resizer extends MovieClip implements PluginInterface {


        /** Reference to the View of the player. **/
        private var view:AbstractView;
        /** Reference to the graphics. **/
        private var clip:MovieClip;
        /** Resizing interval. **/
        private var interval:Number;
        /** initialize call for backward compatibility. **/
        public var initialize:Function = initializePlugin;


        /** Set internal handlers on init. **/
        public function Resizer() {
                clip = this;
                clip.resizeBar.buttonMode = true;
                clip.resizeBar.mouseChildren = false;
                clip.resizeBar.addEventListener(MouseEvent.MOUSE_DOWN,downHandler);
        };


        /** Set the new playlistsize and redraw the stage. **/
        private function doResize() {
                var pls = clip.stage.stageWidth-clip.mouseX-view.config['margins'].split(',')[0];
                view.config['playlistsize'] = pls;
                view.sendEvent('REDRAW');
        };


        /** Start dragging when mouse is down. **/
        private function downHandler(evt:MouseEvent):void {
                interval = setInterval(doResize,50);
        };


        /** The initialize call is invoked by the player View. **/
        public function initializePlugin(vie:AbstractView):void {
                view = vie;
                view.addControllerListener(ControllerEvent.RESIZE,resizeHandler);
                clip.stage.addEventListener(MouseEvent.MOUSE_UP,upHandler);
                resizeHandler();
        };


        /** Handle a resize. **/
        private function resizeHandler(evt:ControllerEvent=undefined) {
                clip.resizeBar.x = view.config['width'];
                clip.resizeBar.height = view.config['height'];
        };


        /** Stop dragging when mouse is up again. **/
        private function upHandler(evt:MouseEvent):void {
                clearInterval(interval);
        };


}


}