source: branches/hds/src/com/longtailvideo/jwplayer/media/HDSMediaProvider.as @ 2265

package com.longtailvideo.jwplayer.media
{


        import com.longtailvideo.jwplayer.events.MediaEvent;
        import com.longtailvideo.jwplayer.model.PlayerConfig;
        import com.longtailvideo.jwplayer.model.PlaylistItem;
        import com.longtailvideo.jwplayer.player.PlayerState;
        import com.longtailvideo.jwplayer.utils.Logger;
        import com.longtailvideo.jwplayer.utils.Stretcher;
        
        import flash.display.DisplayObjectContainer;
        import flash.display.Loader;
        import flash.display.MovieClip;
        import flash.events.ErrorEvent;
        import flash.events.Event;
        import flash.events.EventDispatcher;
        import flash.external.ExternalInterface;
        import flash.utils.clearInterval;
        import flash.utils.setInterval;
        import flash.utils.setTimeout;
        
        import org.osmf.containers.MediaContainer;
        import org.osmf.elements.ImageElement;
        import org.osmf.elements.VideoElement;
        import org.osmf.events.BufferEvent;
        import org.osmf.events.DynamicStreamEvent;
        import org.osmf.events.MediaErrorEvent;
        import org.osmf.events.MediaPlayerStateChangeEvent;
        import org.osmf.events.PlayEvent;
        import org.osmf.events.TimeEvent;
        import org.osmf.media.DefaultMediaFactory;
        import org.osmf.media.MediaElement;
        import org.osmf.media.MediaFactory;
        import org.osmf.media.MediaPlayer;
        import org.osmf.media.URLResource;
        import org.osmf.net.DynamicStreamingResource;
        import org.osmf.net.NetLoader;
        import org.osmf.traits.LoadTrait;
        import org.osmf.traits.MediaTraitType;
        import org.osmf.traits.PlayState;
        import org.osmf.utils.OSMFSettings;
        import org.osmf.utils.URL;
        import org.osmf.events.MediaError;
        import org.osmf.events.MediaErrorCodes;
        
        
        
        public class HDSMediaProvider extends MediaProvider {
                /** OSMF player **/
                protected var _osmfPlayer:MediaPlayer;
                 /**OSMF media container**/
                protected var _container:MediaContainer;
                /**the media element--the subtype is determined by extension**/
                protected var _element:MediaElement;
                /** ID for the position interval. **/
                protected var _positionInterval:Number;

                public function HDSMediaProvider() {
                        //OSMFSettings.enableStageVideo = false;
                        _osmfPlayer = new MediaPlayer();
                        _container = new MediaContainer();
                        _osmfPlayer.addEventListener(TimeEvent.COMPLETE, completeEvent);
                        _osmfPlayer.addEventListener(MediaErrorEvent.MEDIA_ERROR,errorEvent);
                        _osmfPlayer.addEventListener(BufferEvent.BUFFERING_CHANGE,bufferingChangeHandler);
                        _osmfPlayer.addEventListener(TimeEvent.CURRENT_TIME_CHANGE,positionHandler);
                        _osmfPlayer.addEventListener(DynamicStreamEvent.SWITCHING_CHANGE,handleDynamicChange);
                        super("hds");
                }
                                
                /**
                 * Load a new playlist item
                 * @param itm The playlistItem to load
                 **/
                public override function load(itm:PlaylistItem):void {
                        _item = itm;

                        var resource:URLResource = new URLResource( _item.file );

                        var mediaFactory:DefaultMediaFactory = new DefaultMediaFactory();
                        //media factor associates the extension with the right element type. If the extension isn't supported or recognized, returns null
                        _element = mediaFactory.createMediaElement( resource );
                        if (_element == null) {
                                super.load(item);
                                error("Unsupported File Type");
                                return;
                        } 

                        media = _container;
                        _container.addMediaElement(_element);
                        super.load(itm);
                        _osmfPlayer.volume = config.mute ? 0 : config.volume;
                        _osmfPlayer.media = _element;
                }
                

                /**
                 * handles the position of the status bar
                 * 
                 **/
                protected function positionHandler(event:TimeEvent):void {
                        
                        var pos:Number = Math.round(Math.min(_osmfPlayer.currentTime, Math.max(_osmfPlayer.duration, 0)) * 100) / 100;
                        var timeRemaining:Number = _osmfPlayer.duration > 0 ? (_osmfPlayer.duration - _osmfPlayer.currentTime) : _osmfPlayer.currentTime;

                        if (state != PlayerState.PLAYING) {
                                return;
                        }
                        
                        _position = pos;
                        
                        if (position < _osmfPlayer.duration) {
                                if (position >= 0) {
                                        sendMediaEvent(MediaEvent.JWPLAYER_MEDIA_TIME, {position: position, duration: _osmfPlayer.duration});
                                }
                        } 
                }
                
                /**
                 * handles buffer change state. dispatches the needed events
                 * @param the buffer change event
                 **/
                private function bufferingChangeHandler(event:BufferEvent): void
                {
                        if (_osmfPlayer.buffering) {
                                sendBufferEvent(0);
                                setState(PlayerState.BUFFERING);
                        } else if (_osmfPlayer.playing) {

                                dispatchEvent(new MediaEvent(MediaEvent.JWPLAYER_MEDIA_BUFFER_FULL));
                                _item.duration = _osmfPlayer.duration;
                                //fixes size issue
                                resize(_width,_height);
                        }
                }
                
                /**
                 * listen for end of file
                 * @param the play state change event
                 **/
                private function completeEvent(event:TimeEvent):void {
                        complete();
                }
                
                
                /**
                 * listen for dynamic stream change and resize
                 * @param dynamic stream change event
                 **/
                private function handleDynamicChange(event:DynamicStreamEvent):void {
                        resize(_width,_height);
                }
                
                
                /**
                 * listen for errors
                 * @param the error event
                 **/
                private function errorEvent(event:MediaErrorEvent):void {
                        Logger.log(event.error.detail);
                        error("OSMF Playback Error");
                }
                
                /** Resume playback of the item. **/
                public override function play():void {
                        if (_osmfPlayer.paused) { 
                                _osmfPlayer.play();
                        } 
                        super.play();
                }

                /** Pause playback of the item. **/
                public override function pause():void {
                        if (_osmfPlayer.playing) { 
                                _osmfPlayer.pause();
                        }
                        super.pause();
                }
                
        
                /**
                 * Seek to a certain position in the item.
                 *
                 * @param pos   The position in seconds.
                 **/
                /** Seek to a new position. **/
                override public function seek(pos:Number):void {

                        _osmfPlayer.seek(pos);
                        
                        //jw should restart on seek
                        if (_osmfPlayer.paused) {
                                play();
                        }
                }

                
                /** Stop playing and loading the item. **/
                public override function stop():void {
                        if (_osmfPlayer.playing) {
                                _osmfPlayer.stop();
                        }
                        if (_element != null){
                                _container.removeMediaElement(_element);
                                _element = null;
                        }
                        super.stop();
                }
                
                
                /**
                 * Change the playback volume of the item.
                 *
                 * @param vol   The new volume (0 to 100).
                 * note that the osmf volume is [0 to 1]
                 **/
                public override function setVolume(vol:Number):void {
                        _osmfPlayer.volume = vol/100;
                        super.setVolume(vol);
                }
        }
        
}