source: branches/captions/src/com/longtailvideo/plugins/captions/SelectorUpDown.as @ 1808

package com.longtailvideo.plugins.captions {


    import flash.accessibility.AccessibilityProperties;
    import flash.display.*;
    import flash.events.*;
    import flash.text.*;


    /** A selector up or down button. **/
    public class SelectorUpDown extends Sprite {


        /** Embeds of the default graphics. **/
        [Embed(source="../../../../../assets/back.png")]
        private const ButtonBack:Class;
        [Embed(source="../../../../../assets/up.png")]
        private const UpIcon:Class;
        [Embed(source="../../../../../assets/down.png")]
        private const DownIcon:Class;


        /** Background of the button. **/
        private var _back:DisplayObject;
        /** Textfield of the button. **/
        private var _icon:DisplayObject;
        /** Handler to call when the button is clicked. **/
        private var _handler:Function;


        /** Constructor. **/
        public function SelectorUpDown(up:Boolean,handler:Function) {
            _handler = handler;
            _back = new ButtonBack();
            _back.alpha = 0;
            addChild(_back);
            if(up) { 
                _icon = new UpIcon();
            } else {
                _icon = new DownIcon();
            }
            _icon.x = 77;
            addChild(_icon);
            // Insert accessibility options (tabbing / screenreader label).
            tabEnabled = true;
            tabChildren = false;
            buttonMode = true;
            mouseChildren = false;
            var acs:AccessibilityProperties = new AccessibilityProperties();
            if(up) { 
                tabIndex = 500;
                acs.name = "scroll up language list";
            } else { 
                tabIndex = 599;
                acs.name = "scroll down language list";
            }
            accessibilityProperties = acs;
            // Set event handlers.
            addEventListener(MouseEvent.CLICK,_clickHandler);
            addEventListener(MouseEvent.MOUSE_OUT,_outHandler);
            addEventListener(MouseEvent.MOUSE_OVER,_overHandler);
        };


        /** Register the click. **/
        private function _clickHandler(event:MouseEvent):void { 
            _handler();
        };


        /** Fade the back on rollover. **/
        private function _outHandler(event:MouseEvent):void { 
            _back.alpha = 0;
        };


        /** Fade the back on rollover. **/
        private function _overHandler(event:MouseEvent):void {
            _back.alpha = 1;
        };

    };


}