source: branches/captions/src/com/longtailvideo/plugins/captions/SelectorButton.as @ 1754

package com.longtailvideo.plugins.captions {


    import flash.display.*;
    import flash.events.*;
    import flash.text.*;


    /** A single selector button. **/
    public class SelectorButton extends Sprite {


        /** Embeds of the default graphics. **/
        [Embed(source="../../../../../assets/divider.png")]
        private const ButtonBack:Class;
        [Embed(source="../../../../../assets/active.png")]
        private const ActiveIcon:Class;


        /** The icon that indicates the item is active. **/
        private var _active:DisplayObject;
        /** Background of the button. **/
        private var _back:DisplayObject;
        /** Textfield of the button. **/
        private var _field:TextField;
        /** Label of the textfield. **/
        private var _label:String;
        /** Formatting of the textfield. **/
        private var _format:TextFormat;
        /** Handler to call when the button is clicked. **/
        private var _handler:Function;
        /** Index of the button. **/
        private var _index:Number;


        /** Constructor. **/
        public function SelectorButton(handler:Function,index:Number,label:String) {
            _handler = handler;
            _index = index;
            _label = label;
            _back = new ButtonBack();
            _back.height = 30;
            _back.alpha = 0;
            addChild(_back);
            _field = new TextField();
            addChild(_field);
            // Create the text formatting.
            _format = new TextFormat();
            _format.color = 0xFFFFFF;
            _format.size = 12;
            _format.align = TextFormatAlign.LEFT;
            _format.font = "_sans";
            _field.defaultTextFormat = _format;
            // Set other textfield props.
            _field.selectable = false;
            _field.height = 20;
            _field.x = 80;
            _field.width = 160;
            _field.y = _back.height/2 - 9;
            _field.htmlText = label;
            buttonMode = true;
            mouseChildren = false;
            _active = new ActiveIcon();
            _active.x = 65;
            _active.y = 12;
            _active.visible = false;
            addChild(_active);
            addEventListener(MouseEvent.CLICK,_clickHandler);
            addEventListener(MouseEvent.MOUSE_OUT,_outHandler);
            addEventListener(MouseEvent.MOUSE_OVER,_overHandler);
        };


        /** (de)activate the button. **/
        public function activate(state:Boolean):void {
            if(state) { 
                _field.htmlText = '<b>'+_label+'</b>';
                _active.visible = true;
            } else {
                _field.htmlText = _label;
                _active.visible = false;
            }
        };


        /** Register the click. **/
        private function _clickHandler(event:MouseEvent):void { 
            _handler(_index);
        };


        /** Fade the back on rollover. **/
        private function _outHandler(event:MouseEvent):void { 
            _back.alpha = 0;
        };


        /** Fade the back on rollover. **/
        private function _overHandler(event:MouseEvent):void {
            _back.alpha = 0.3;
        };

    };


}