source: branches/captions/src/com/longtailvideo/plugins/captions/Selector.as @ 1808

package com.longtailvideo.plugins.captions {


    import com.longtailvideo.jwplayer.utils.Logger;

    import flash.display.*;
    import flash.events.*;


    /** Component that renders a select box. **/
    public class Selector extends Sprite {


        /** Compiles of the default graphics. **/
        [Embed(source="../../../../../assets/divider.png")]
        private const DividerRow:Class;
        [Embed(source="../../../../../assets/sheet.png")]
        private const BackSheet:Class;


        /** currently active option. **/
        private var _active:Number;
        /** Background graphic. **/
        private var _back:Sprite;
        /** Container for the buttons. **/
        private var _container:Sprite;
        /** Function to call when a selection is made. **/
        private var _callback:Function;
        /** Reference to the page down button. **/
        private var _down:SelectorUpDown;
        /** Offset of the visible entries. **/
        private var _offset:Number;
        /** List with options from the selector. **/
        private var _options:Array;
        /** Reference to the page up button. **/
        private var _up:SelectorUpDown;


        /** Constructor. **/
        public function Selector(callback:Function) {
            _callback = callback;
            _back = new Sprite();
            _back.addChild(new BackSheet());
            addChild(_back);
            _back.buttonMode = true;
            _back.addEventListener(MouseEvent.CLICK,_backHandler);
            _container = new Sprite();
            addChild(_container);
            _container.buttonMode = true;
            _down = new SelectorUpDown(false,_downHandler);
            _up = new SelectorUpDown(true,_upHandler);
        };


        /** Background was clicked. **/
        private function _backHandler(event:MouseEvent):void {
            _buttonHandler(_active);
        }; 


        /** Button was clicked. **/
        private function _buttonHandler(index:Number):void {
            _options[_active].button.activate(false);
            _options[index].button.activate(true);
            _active = index;
            _callback(index);
        };


        /** The down button was clicked. **/
        private function _downHandler():void {
            _offset++;
            _redraw(false);
        };


        /** Return the max number of buttons that fit in the screen. **/
        private function _max():Number { 
            return Math.floor(_back.height/27) - 2;
        };


        /** Populate the selector with a number of items. **/
        public function populate(options:Array,active:Number=0):void {
            _options = options;
            _active = active;
            // Build all the buttons.
            for(var i:Number=0; i < _options.length; i++) {
                _options[i].button = new SelectorButton(_buttonHandler,i,_options[i].label);
            }
            _options[_active].button.activate(true);
            // Set a sane default offset.
            if(_active < _max()) {
                _offset = 0;
            } else if(_options.length > _max() && _active > _options.length - _max()) {
                _offset = _options.length - _max();
            } else { 
                _offset = _active;
            }
            // Redraw the menu.
            _redraw();
        };


        /** Draw visible portion of the options. **/
        private function _redraw(show:Boolean=true):void {
            var button:SelectorButton;
            var height:Number = 0;
            var end:Number;
            var scroll:Boolean;
            // clear existing buttons.
            while(_container.numChildren > 0) {
                _container.removeChildAt(0);
            }
            // Check if scrollbars are needed and if offset needs correcting.
            if(_options.length > _max()) {
                scroll = true;
                end = _max();
            } else {
                end = _options.length;
            }
            if(_offset < 0) {
                _offset = 0;
            } else if (scroll && _offset > _options.length - _max()) {
                _offset = _options.length - _max();
            }
            // Draw prev button if needed.
            if(scroll) {
                _container.addChild(_up);
                _up.y = height;
                _offset == 0 ? _up.alpha = 0: _up.alpha = 1;
                height += 26;
                height = _redrawDivider(height);
            }
            // Draw new buttons and dividers
            for(var i:Number = _offset; i < _offset + end; i++) {
                _container.addChild(_options[i].button);
                _options[i].button.y = height;
                height += 26;
                if(i < _offset + end - 1) {
                    height = _redrawDivider(height);
                }
            }
            //draw next button if needed
            if(scroll) {
                height = _redrawDivider(height);
                _container.addChild(_down);
                _down.y = height;
                _offset == _options.length - _max() ? _down.alpha = 0: _down.alpha = 1;
                height += 26;
            }
            // Rescale button list.
            _container.x = Math.round(_back.width/2 - _container.width/2);
            _container.y = Math.round(_back.height/2 - height/2);
        };


        private function _redrawDivider(height:Number):Number {
            var divider:DisplayObject = new DividerRow();
            _container.addChild(divider);
            divider.y = height;
            return height + 1;
        };


        /** Resize the selector screen. **/
        public function resize(width:Number,height:Number):void {
            _back.width = width;
            _back.height = height;
            if(_options) { 
                _redraw();
            }
        };


        /** The up button was clicked. **/
        private function _upHandler():void {
            _offset --;
            _redraw(false);
        };


};


}