source: branches/captions/src/com/longtailvideo/plugins/captions/Selector.as @ 1754

package com.longtailvideo.plugins.captions {


    import flash.display.*;
    import flash.events.*;


    /** Component that renders a select box. **/
    public class Selector extends Sprite {


        /** Compiles of the default graphics. **/
        [Embed(source="../../../../../assets/down.png")]
        private const DownIcon:Class;
        [Embed(source="../../../../../assets/divider.png")]
        private const DividerRow:Class;
        [Embed(source="../../../../../assets/up.png")]
        private const UpIcon:Class;


        /** currently active option. **/
        private var _active:Number;
        /** Background graphic. **/
        private var _back:Sprite;
        /** Container for the buttons. **/
        private var _container:Sprite;
        /** Function to call when a selection is made. **/
        private var _callback:Function;
        /** Reference to the down clip. **/
        private var _down:Sprite;
        /** List with options from the selector. **/
        private var _options:Array;
        /** List with buttons in the container. **/
        private var _buttons:Array;
        /** Reference to the up clip. **/
        private var _up:Sprite;


        /** Constructor. **/
        public function Selector(callback:Function) {
            _callback = callback;
            _drawBack();
        };


        /** Background was clicked. **/
        private function _backHandler(event:MouseEvent):void { 
            _buttonHandler(_active);
        }; 


        /** Button was clicked. **/
        private function _buttonHandler(index:Number):void {
            _buttons[_active].activate(false);
            _buttons[index].activate(true);
            _active = index;
            _callback(index);
        }; 


        /** Draw the background graphic. **/
        private function _drawBack():void {
            _back = new Sprite();
            _back.graphics.beginFill(0x000000,0.8);
            _back.graphics.drawRect(0,0,320,240);
            addChild(_back);
            _back.buttonMode = true;
            _back.addEventListener(MouseEvent.CLICK,_backHandler);
            _container = new Sprite();
            addChild(_container);
            _container.buttonMode = true;
        };


        /** Populate the selector with a number of items. **/
        public function populate(options:Array,active:Number=0):void {
            var offset:Number = 0;
            var button:SelectorButton;
            var divider:DisplayObject;
            // clear existing buttons.
            while(_container.numChildren > 0) {
                _container.removeChildAt(0);
            }
            _buttons = new Array();
            // Draw new buttons.
            for(var i:Number=0; i <= options.length; i++) {
                    divider = new DividerRow();
                    _container.addChild(divider);
                    divider.y = offset;
                    offset++;
                if(i < options.length) {
                button = new SelectorButton(_buttonHandler,i,options[i]);
                _buttons.push(button);
                _container.addChild(button);
                button.y = offset;
                offset += button.height;
                }
            }
            // Select initial option and set dimensions.
            _buttons[active].activate(true);
            _active = active;
            resize(_back.width, _back.height);
        };


        /** Resize the selector screen. **/
        public function resize(width:Number,height:Number):void { 
            _back.width = width;
            _back.height = height;
            _container.x = Math.round(width/2 - _container.width/2);
            _container.y = Math.round(height/2 - _container.height/2);
        };


};


}