source: branches/4.2/com/jeroenwijering/player/Player.as @ 68

/**
* Player that crunches through all media formats Flash can read.
**/
package com.jeroenwijering.player {


import com.jeroenwijering.player.*;
import com.jeroenwijering.plugins.*;
import com.jeroenwijering.utils.Configger;
import flash.display.MovieClip;
import flash.events.Event;


public class Player extends MovieClip {


        /** A list with all default configuration values. Change them to hard-code your preferences. **/
        public var config:Object = {
                author:undefined,
                description:undefined,
                date:undefined,
                duration:0,
                file:undefined,
                image:undefined,
                link:undefined,
                start:0,
                tags:undefined,
                title:undefined,
                type:undefined,

                backcolor:undefined,
                frontcolor:undefined,
                lightcolor:undefined,
                screencolor:undefined,

                controlbar:'bottom',
                controlbarsize:20,
                height:300,
                icons:true,
                logo:undefined,
                playlist:'none',
                playlistsize:180,
                skin:undefined,
                width:400,

                autostart:false,
                bufferlength:1,
                displayclick:'play',
                item:0,
                mute:false,
                quality:true,
                repeat:'none',
                shuffle:false,
                state:'IDLE',
                stretching:'uniform',
                volume:80,

                abouttext:undefined,
                aboutlink:"http://www.jeroenwijering.com/?item=JW_FLV_Player",
                client:undefined,
                id:undefined,
                linktarget:'_blank',
                margins:'0,0',
                plugins:undefined,
                streamer:undefined,
                token:undefined,
                tracer:undefined,
                version:'4.2.67'
        };
        /** Reference to all stage graphics. **/
        public var skin:MovieClip;
        /** Object that loads all configuration variables. **/
        private var configger:Configger;
        /** Object that load the skin and plugins. **/
        private var loader:SWFLoader;
        /** Reference to the Controller of the MVC cycle. **/
        private var controller:Controller;
        /** Reference to the model of the MVC cycle. **/
        private var model:Model;
        /** Reference to the View of the MVC cycle, which defines all API calls. **/
        public var view:View;


        /** 
        * Constructor; initializes and starts the player.
        **/
        public function Player():void {
                visible = false;
                skin = this.player;
                addEventListener(Event.ADDED_TO_STAGE,loadConfig);
        };


        /** When added to stage, the player loads the config. **/
        private function loadConfig(evt:Event):void { 
                configger = new Configger(this);
                configger.addEventListener(Event.COMPLETE,loadSkin);
                configger.load(config);
        };


        /** Config loading completed; now load skin. **/
        private function loadSkin(evt:Event):void {
                loader = new SWFLoader(this);
                loader.addEventListener(Event.COMPLETE,loadMVC);
                loader.loadSkin(config['skin']);
        };


        /** Skin loading completed, now load MVC. **/
        private function loadMVC(evt:Event):void {
                controller = new Controller(config,skin);
                model = new Model(config,skin,controller);
                view = new View(config,skin,controller,model,loader);
                controller.start(model,view);
                loadPlugins();
        };


        /** MVC inited; now load plugins. **/
        private function loadPlugins() {
                new Rightclick().initializePlugin(view);
                new Display().initializePlugin(view);
                new Controlbar().initializePlugin(view);
                if(skin['playlist']) { new Playlist().initializePlugin(view); }
                loader.loadPlugins(config['plugins']);
                visible = true;
        };


}


}